.子程序 _啟動子程序, 整數型, , 請在本子程序中放置易模塊初始化代碼

載入 (窗口1, , 假)

_臨時子程序 ()  ' 在初始化代碼執行完畢后調用測試代碼

返回 (0)  ' 可以根據您的需要返回任意數值

.子程序 _臨時子程序

' 本名稱子程序用作測試程序用，僅在開發及調試環境中有效，編譯發布程序前將被系統自動清空，請將所有用作測試的臨時代碼放在本子程序中。 ***注意不要修改本子程序的名稱、參數及返回值類型。

.子程序 取后綴名圖標_SHG, 字節集, 公開, 取自 凌晨孤星 開源代碼.API  返回png圖片

.參數 參_后綴, 文本型, , .txt(取快捷方式圖標，請填寫全路徑)

.局部變量 文件信息, SHFILEINFO

SHGetFileInfo (參_后綴, 128, 文件信息, 348, 272)

返回 (轉換圖標_從句柄 (文件信息.hIcon))

.子程序 取后綴名圖標_注冊表, 字節集, 公開, 通過注冊表取本機后綴圖標  返回png圖片

.參數 參_后綴, 文本型, , .txt

.參數 是否小圖標, 邏輯型, 可空, 默認為假，取大圖標。  大圖標(32*32)  小圖標(16*16)

.局部變量 Text, 文本型

.局部變量 Text_注冊表, 文本型

.局部變量 局_Path, 文本型

.局部變量 局_索引, 整數型

.局部變量 hIco32, 整數型

.局部變量 hIco16, 整數型

.局部變量 a, 整數型

Text ＝ 取文本右邊 (參_后綴, 取文本長度 (參_后綴) － 倒找文本 (參_后綴, “.”, , 假) ＋ 1)  ' 帶后綴的文件名，取出后綴名

Text_注冊表 ＝ 取文本注冊項 (#根類, 取文本注冊項 (#根類, Text ＋ “\”, ) ＋ “\DefaultIcon\”, )  ' C:\Windows\system32\imageres.dll,-102

' 輸出調試文本 (Text_注冊表)

局_Path ＝ 取文本左邊 (Text_注冊表, 倒找文本 (Text_注冊表, “,”, , 假) － 1)

局_索引 ＝ 到整數 (取文本右邊 (Text_注冊表, 取文本長度 (Text_注冊表) － 倒找文本 (Text_注冊表, “,”, , 假)))

a ＝ ExtractIconEx (局_Path, 局_索引, hIco32, hIco16, 1)

.如果真 (a ＝ -1)  ' 是否失敗

    .判斷開始 (Text ＝ “.exe”)

        返回 (#exe)

    .默認

        返回 (#空)

    .判斷結束

.如果真結束

.判斷開始 (是否為空 (是否小圖標))

    返回 (轉換圖標_從句柄 (hIco32, 假))

.默認

    返回 (轉換圖標_從句柄 (hIco16, 假))

.判斷結束